Untitled

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)
	СуммаПоДокументу = СписокНоменклатуры.Итог("Сумма");
КонецПроцедуры
Процедура ОбработкаПроведенияБУ(Отказ)
	
	Если Не БУ Тогда
		Возврат;
	КонецЕсли;
	
	// Определение текущего метода списания себестоимости
	МетодСписания = РегистрыСведений.УчетнаяПолитика.ПолучитьПоследнее(МоментВремени()).МетодСписания;
	
	Если Не ЗначениеЗаполнено(МетодСписания) Тогда
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = "Не заполнена учетная политика";
		Сообщение.Сообщить();
		
		Отказ = Истина;		
		Возврат;
	КонецЕсли;
	
	// ДВИЖЕНИЯ ПО РЕГИСТРУ УПРАВЛЕНЧЕСКИЙ (СТАРАЯ МЕТОДИКА ПРОВЕДЕНИЯ)
	
	Движения.Управленческий.Записывать = Истина;
	Движения.Управленческий.Записать();
	
	// Установка блокировки данных в регистре Управленческий по счету Товары и списку номенклатур табличной части
	Блокировка = Новый БлокировкаДанных;
	ЭлементБлокировки = Блокировка.Добавить("РегистрБухгалтерии.Управленческий");
	ЭлементБлокировки.УстановитьЗначение("Счет", ПланыСчетов.Управленческий.Товары);
	ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
	ЭлементБлокировки.ИсточникДанных = СписокНоменклатуры;
	ЭлементБлокировки.ИспользоватьИзИсточникаДанных(ПланыВидовХарактеристик.ВидыСубконто.Номенклатура, "Номенклатура");
	Блокировка.Заблокировать();
	
	// Запрос получения данных для формирования движений
	Запрос = Новый Запрос;
	ТекстЗапроса = 
	"ВЫБРАТЬ
	|	РасходнаяНакладнаяСписокНоменклатуры.Номенклатура КАК Номенклатура,
	|	СУММА(РасходнаяНакладнаяСписокНоменклатуры.Количество) КАК Количество
	|ПОМЕСТИТЬ ВТ_ТабЧасть
	|ИЗ
	|	Документ.РасходнаяНакладная.СписокНоменклатуры КАК РасходнаяНакладнаяСписокНоменклатуры
	|ГДЕ
	|	РасходнаяНакладнаяСписокНоменклатуры.Ссылка = &Ссылка
	|
	|СГРУППИРОВАТЬ ПО
	|	РасходнаяНакладнаяСписокНоменклатуры.Номенклатура
	|
	|ИНДЕКСИРОВАТЬ ПО
	|	Номенклатура
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ
	|	ВТ_ТабЧасть.Номенклатура КАК Номенклатура,
	|	ВТ_ТабЧасть.Номенклатура.Представление КАК НоменклатураПредставление,
	|	УправленческийОстаткиПоПартиям.Субконто2 КАК Партия,
	|	ВТ_ТабЧасть.Количество КАК КоличествоВДокументе,
	|	ЕСТЬNULL(УправленческийОстаткиПоСкладамИПартиям.КоличествоОстаток, 0) КАК КоличествоОстатокНаСкладе,
	|	ЕСТЬNULL(УправленческийОстаткиПоПартиям.КоличествоОстаток, 0) КАК КоличествоОстатокПоПартии,
	|	ЕСТЬNULL(УправленческийОстаткиПоПартиям.СуммаОстаток, 0) КАК СуммаОстатокПоПартии,
	|	ВЫРАЗИТЬ(УправленческийОстаткиПоПартиям.Субконто2 КАК Документ.ПриходнаяНакладная).МоментВремени КАК МоментВремениПартии
	|ИЗ
	|	ВТ_ТабЧасть КАК ВТ_ТабЧасть
	|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Управленческий.Остатки(
	|				&МоментВремени,
	|				Счет = &СчетТовары,
	|				&СубконтоСкладыПартии,
	|				Субконто1 В
	|						(ВЫБРАТЬ
	|							ВТ_ТабЧасть.Номенклатура
	|						ИЗ
	|							ВТ_ТабЧасть КАК ВТ_ТабЧасть)
	|					И Субконто2 = &Склад) КАК УправленческийОстаткиПоСкладамИПартиям
	|			ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Управленческий.Остатки(
	|					&МоментВремени,
	|					Счет = &СчетТовары,
	|					&СубконтоПартии,
	|					Субконто1 В
	|						(ВЫБРАТЬ
	|							ВТ_ТабЧасть.Номенклатура
	|						ИЗ
	|							ВТ_ТабЧасть КАК ВТ_ТабЧасть)) КАК УправленческийОстаткиПоПартиям
	|			ПО УправленческийОстаткиПоСкладамИПартиям.Субконто1 = УправленческийОстаткиПоПартиям.Субконто1
	|				И УправленческийОстаткиПоСкладамИПартиям.Субконто3 = УправленческийОстаткиПоПартиям.Субконто2
	|		ПО ВТ_ТабЧасть.Номенклатура = УправленческийОстаткиПоСкладамИПартиям.Субконто1
	|
	|УПОРЯДОЧИТЬ ПО
	|	МоментВремениПартии УБЫВ
	|ИТОГИ
	|	МАКСИМУМ(КоличествоВДокументе),
	|	СУММА(КоличествоОстатокНаСкладе)
	|ПО
	|	Номенклатура";
	
	Если МетодСписания = Перечисления.МетодыСписания.ФИФО Тогда
		ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "УБЫВ", "");
	КонецЕсли;
	
	Запрос.Текст = ТекстЗапроса;
	
	СубконтоСкладыПартии = Новый Массив(3);
	СубконтоСкладыПартии[0] = ПланыВидовХарактеристик.ВидыСубконто.Номенклатура;
	СубконтоСкладыПартии[1] = ПланыВидовХарактеристик.ВидыСубконто.Склады;
	СубконтоСкладыПартии[2] = ПланыВидовХарактеристик.ВидыСубконто.Партии;
	
	СубконтоПартии = Новый Массив(2);
	СубконтоПартии[0] = ПланыВидовХарактеристик.ВидыСубконто.Номенклатура;
	СубконтоПартии[1] = ПланыВидовХарактеристик.ВидыСубконто.Партии;
	
	Запрос.УстановитьПараметр("Ссылка", Ссылка);
	Запрос.УстановитьПараметр("МоментВремени", МоментВремени());
	Запрос.УстановитьПараметр("Склад", Склад);
	Запрос.УстановитьПараметр("СчетТовары", ПланыСчетов.Управленческий.Товары);
	Запрос.УстановитьПараметр("СубконтоСкладыПартии",СубконтоСкладыПартии);
	Запрос.УстановитьПараметр("СубконтоПартии",СубконтоПартии);
	
	// Обход результатов запроса
	ВыборкаНоменклатура = Запрос.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
	Пока ВыборкаНоменклатура.Следующий() Цикл
		// Контроль наличия номенклатуры
		Превышение = ВыборкаНоменклатура.КоличествоВДокументе - ВыборкаНоменклатура.КоличествоОстатокНаСкладе;
		Если Превышение > 0 Тогда
			Сообщение = Новый СообщениеПользователю;
			Сообщение.Текст = СтрШаблон("Превышение остатка по номенклатуре %1 в количестве %2", 
				ВыборкаНоменклатура.НоменклатураПредставление, Превышение);						                      
			Сообщение.Сообщить();
			
			Отказ = Истина;
		КонецЕсли;
		
		Если Отказ Тогда 
			Продолжить;
		КонецЕсли;
		
		// Переменная для прерывания обхода партий после того как будет списано все количество из документа
		ОсталосьСписать = ВыборкаНоменклатура.КоличествоВДокументе;
		
		Выборка = ВыборкаНоменклатура.Выбрать();
		Пока Выборка.Следующий() и ОсталосьСписать <> 0 Цикл
			// Проводка отражения списания товара
			Списываем = Мин (ОсталосьСписать, Выборка.КоличествоОстатокНаСкладе);
			Проводка = Движения.Управленческий.Добавить();
			
			Проводка.Период = Дата;
			Проводка.СчетДт = ПланыСчетов.Управленческий.ПрибылиУбытки;
			Проводка.СчетКт = Планысчетов.Управленческий.Товары;
			Проводка.СубконтоКт[ПланыВидовХарактеристик.ВидыСубконто.Номенклатура] = Выборка.Номенклатура;
			Проводка.СубконтоКт[ПланыВидовХарактеристик.ВидыСубконто.Партии] = Выборка.Партия;
			Проводка.СубконтоКт[ПланыВидовХарактеристик.ВидыСубконто.Склады] = Склад;
			
			Проводка.КоличествоКт = Списываем;
			Проводка.Сумма = Списываем / Выборка.КоличествоОстатокПоПартии * Выборка.СуммаОстатокПоПартии;
			
			ОсталосьСписать = ОсталосьСписать - Списываем;
		КонецЦикла;
		
		
	КонецЦикла;
	
	// Проводка отражения продажи товара
	Проводка = Движения.Управленческий.Добавить();
	Проводка.Период = Дата;
	Проводка.СчетДт = ПланыСчетов.Управленческий.Покупатели;
	Проводка.СчетКт = Планысчетов.Управленческий.ПрибылиУбытки;
	Проводка.Сумма = СуммаПоДокументу;   	

КонецПроцедуры