Untitled

ВЫБРАТЬ РАЗЛИЧНЫЕ
	ОстаткиНоменклатурыОстатки.Склад КАК Склад,
	СоставСтеллажей.Стеллаж КАК Стеллаж
ПОМЕСТИТЬ ВТ_СтелажиПоСкладамСДеталямиВОстатках
ИЗ
	РегистрНакопления.ОстаткиНоменклатуры.Остатки(, ) КАК ОстаткиНоменклатурыОстатки
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.СоставСтеллажей КАК СоставСтеллажей
		ПО ОстаткиНоменклатурыОстатки.Номенклатура = СоставСтеллажей.Деталь

ИНДЕКСИРОВАТЬ ПО
	Стеллаж
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_СтелажиПоСкладамСДеталямиВОстатках.Склад КАК Склад,
	ВТ_СтелажиПоСкладамСДеталямиВОстатках.Стеллаж КАК Стеллаж,
	СоставСтеллажей.Деталь КАК Деталь,
	СоставСтеллажей.Количество КАК Количество
ПОМЕСТИТЬ ВТ_ДанныеПоСоставуСтеллажей
ИЗ
	ВТ_СтелажиПоСкладамСДеталямиВОстатках КАК ВТ_СтелажиПоСкладамСДеталямиВОстатках
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.СоставСтеллажей КАК СоставСтеллажей
		ПО ВТ_СтелажиПоСкладамСДеталямиВОстатках.Стеллаж = СоставСтеллажей.Стеллаж

ИНДЕКСИРОВАТЬ ПО
	Деталь,
	Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_ДанныеПоСоставуСтеллажей.Склад КАК Склад,
	ВТ_ДанныеПоСоставуСтеллажей.Стеллаж КАК Стеллаж,
	МИНИМУМ(ЕСТЬNULL(ОстаткиНоменклатурыОстатки.КоличествоОстаток, 0) / ВТ_ДанныеПоСоставуСтеллажей.Количество) КАК Количество
ИЗ
	ВТ_ДанныеПоСоставуСтеллажей КАК ВТ_ДанныеПоСоставуСтеллажей
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ОстаткиНоменклатуры.Остатки(
				,
				(Номенклатура, Склад) В
					(ВЫБРАТЬ
						ВТ_ДанныеПоСоставуСтеллажей.Деталь КАК Деталь,
						ВТ_ДанныеПоСоставуСтеллажей.Склад КАК Склад
					ИЗ
						ВТ_ДанныеПоСоставуСтеллажей КАК ВТ_ДанныеПоСоставуСтеллажей)) КАК ОстаткиНоменклатурыОстатки
		ПО ВТ_ДанныеПоСоставуСтеллажей.Склад = ОстаткиНоменклатурыОстатки.Склад
			И ВТ_ДанныеПоСоставуСтеллажей.Деталь = ОстаткиНоменклатурыОстатки.Номенклатура

СГРУППИРОВАТЬ ПО
	ВТ_ДанныеПоСоставуСтеллажей.Склад,
	ВТ_ДанныеПоСоставуСтеллажей.Стеллаж

ИМЕЮЩИЕ
	МИНИМУМ(ЕСТЬNULL(ОстаткиНоменклатурыОстатки.КоличествоОстаток, 0) / ВТ_ДанныеПоСоставуСтеллажей.Количество) >= 1